# Configurational entropy s_conf as a function of inverse reduced pressure 1/Z.
# This plot contains two estimates of s_conf based on the PTS length, using
# different values of the theta exponent: theta=2 and theta=3/2 (see main text).
#
# Notes:
# - deltaQ = Q_{high} - Q_{low} = 0.8 - 0.05 = 0.75
# - xi0 = 2.0 and xi0prime = 2.1 are prefactors entering the PTS-based calculation of s_conf (see text)
# - smix = 1.98 is the mixing entropy

# Parameters
smix=1.98  # mixing entropy constant
deltaQ=0.75
xi0=2.0
xi0prime=2.1

load "_defaults.gp"
set out "sconf.eps"
set size 1,1.15
set border 3
set xtics nomirror
set ytics nomirror
set bmargin 3
set tmargin 1
set lmargin 6
set rmargin 3.5
set key at graph 0.72,0.96 noreverse Right width -5 spacing 1.6

set arrow 2 from 1/Zo,graph 0.12 to 1/Zo,graph 0.01 head lw 2 size screen 0.02, 25
set arrow 3 from 1/Zc,graph 0.12 to 1/Zc,graph 0.01 head lw 2  size screen 0.02, 25
set label 2 'Z_o' at 1/Zo-0.004,graph 0.05
set label 3 'Z_c' at 1/Zc-0.004,graph 0.05
set object 1 rectangle back from 1/Zgexp1,graph 0.7 to 1/Zgexp2,graph 0.0001  fc rgb "#3360B1" fs border rgb "white" solid 0.2
set xlab 'Inverse reduced pressure, 1/Z = {/Symbol r}k_BT/P'
set ylab 'Configurational entropy' offset 1.5
set yr [0:2.2]
set xr [0.:0.06]
set ytics 0,1,3

p \
  's_config_modBMCSL_plus_linear_fit.dat' u (YZ($1) > 23.5 ? 1/YZ($1) : 1/0):($2+smix) noti w l lt 3 lw 2 dt 3 lc rgb blue_dark, \
  'cavityPTS.dat' u (1/$4):(xi0/$2) t '{/Symbol x}_0 / {/Symbol x}_{PTS}' w lp pt 5 ps 1.8 lw 2 lt 1 lc rgb black, \
  'cavityPTS.dat' u (1/$4):((xi0prime/$2)**1.5) t "({/Symbol x}@_0^{/*0.8\111}  / {/Symbol x}_{PTS})^{3/2}" w lp pt 13 ps 2.4 lw 2 lt 1 lc rgb black, \
  'sconf_N1000_Z.dat' u (1/$2):($3+smix) t 's_{tot}-s_{vib}' w lp pt 7 lt 1 lw 2 ps 1.8 lc rgb blue_dark, \
  'epsilon_VQ.dat' u (1/$1):($2*deltaQ) t '{/Symbol e}* (Q_{high}-Q_{low})'  w lp pt 11 ps 2.4 lw 2 lt 1 lc rgb green_dark, \
  'epsilon_VQ.dat' u ($1<22.2 ? 1/$1 : 1/0):3 t 'V(Q_{high})-V(Q_{low})' w lp pt 9 ps 2.4 lt 1 lw 2 lc rgb red_dark, \
  'epsilon_VQ.dat' u ($1>22.2 ? 1/$1 : 1/0):3 noti w lp pt 9 ps 2.4 lt 1 lw 2 lc rgb red_dark